PB Vipmenu

Kuidas lisada serveri paintball vipmenu-sse asju juurde?
Mul oleks vaja nt et silent walk  saaks valida vipmenu-st

Kasutad seda: http://www.faval.eu/t1275-amxx-paintballi-vipmenuu?
Tuleb juurde lisada scripti.

Jah kasutan seda

Mis juurde tahad? Ei viitsi mitu korda muuta.

//Kuna vastust ei tulnud, siis:

Kood:

#include <amxmodx>
#include <amxmisc>
#include <colorchat>
#include <cstrike>
#include <fun>
#include <hamsandwich>
#include <engine>
#include <fakemeta>

#define PLUGIN "Paintball VIP"
#define VERSION "2.1"
#define AUTHOR "QzeT"

new const Prefix[ ] = "^04[VIPMenüü]^01"

new bool:Kasutanud[33]
new bool:Unlimited[33]
new bool:Kiiirus[33]

new Kiirus, Gravity, Invis, Elud, Armor

public plugin_init() {
    register_plugin(PLUGIN, VERSION, AUTHOR)
    register_clcmd("say /vipmenu", "VIPMenu")
    register_clcmd("say_team /vipmenu", "VIPMenu")
   
    register_event( "CurWeapon", "RelvaEvent", "be", "1=1")
    RegisterHam(Ham_Spawn, "player", "Spawnimine", 1)
   
    Kiirus            = register_cvar("amx_kiirus",        "420.0")
    Gravity            = register_cvar("amx_gravity",      "0.6")
    Invis              = register_cvar("amx_invisible",      "62")
    Elud              = register_cvar("amx_elud",          "100")
    Armor              = register_cvar("amx_armor",        "100")
}

public VIPMenu(id)
{
    if(!is_user_alive(id)){
        ColorChat(id, NORMAL, "%s Ainult elus mängija saab kasutada vipmenüüd", Prefix)
        return PLUGIN_HANDLED
    }
   
    if(Kasutanud[id]){
        ColorChat(id, NORMAL, "%s Sa oled juba kasutanud vipmenüüd", Prefix)
        return PLUGIN_HANDLED
    }
   
    if(get_user_flags(id) & ADMIN_LEVEL_H)
    {
        new menu = menu_create("VIPMenüü", "VIPMenyHandler")
       
        menu_additem(menu, "Unlimited Ammo", "1", 0)
        menu_additem(menu, "Kiirus", "2", 0)
        menu_additem(menu, "Gravity", "3", 0)
        menu_additem(menu, "Nähtamatus", "4", 0)
        menu_additem(menu, "Elud ja Armor", "5", 0)
        menu_additem(menu, "Granaadid", "6", 0)
      menu_additem(menu, "Silent Walk", "7", 0)

       
        menu_setprop(menu, MPROP_EXIT, MEXIT_ALL)
        menu_display(id, menu)
       
        return PLUGIN_HANDLED
    }
    else ColorChat(id, NORMAL, "%s VIPMenüüd saavad kasutada ainult VIPid", Prefix)
    return PLUGIN_HANDLED
}

public VIPMenyHandler(id, menu, item)
{
    if(!is_user_alive(id))
    {
        menu_destroy(menu)
        return PLUGIN_HANDLED
    }
   
    if(item == MENU_EXIT)
    {
        menu_destroy(menu)
        return PLUGIN_HANDLED
    }
   
    new data[6], szName[64];
    new access, callback;
    menu_item_getinfo(menu, item, access, data,charsmax(data), szName,charsmax(szName), callback);
    new key = str_to_num(data);
    switch(key)
    {
        case 1:{
            Unlimited[id] = true
            ColorChat(id, NORMAL, "%s Võtsid ^3Unlimited Ammo^1.", Prefix)
            Kasutanud[id] = true
        }
        case 2:{
            set_user_maxspeed(id, get_pcvar_float(Kiirus))
            ColorChat(id, NORMAL, "%s Võtsid ^3Kiiruse^1.", Prefix)
            Kasutanud[id] = true
            Kiiirus[id] = true
        }
        case 3:{
            set_user_gravity(id, get_pcvar_float(Gravity))
            ColorChat(id, NORMAL, "%s Võtsid ^3Gravity^1.", Prefix)
            Kasutanud[id] = true
        }
        case 4:{
            set_user_rendering(id,kRenderFxGlowShell,0,0, 0,kRenderTransAlpha, get_pcvar_num(Invis))
            ColorChat(id, NORMAL, "%s Võtsid ^3Nähtamatuse^1.", Prefix)
            Kasutanud[id] = true
        }
        case 5:{
            set_user_health(id, get_pcvar_num(Elud))
            set_user_armor(id, get_pcvar_num(Armor))
            ColorChat(id, NORMAL, "%s Võtsid ^3Elud ja Armori^1.", Prefix)
            Kasutanud[id] = true
        }   
        case 6:{
            give_item(id, "weapon_hegrenade")
            give_item(id, "weapon_smokegrenade")
            give_item(id, "weapon_flashbang")
            give_item(id, "weapon_flashbang")
            ColorChat(id, NORMAL, "%s Võtsid ^3Granaadid^1.", Prefix)
            Kasutanud[id] = true
        }
        case 7:{
            set_user_footsteps(id, 1)
            ColorChat(id, NORMAL, "%s Võtsid ^3Silent Walki^1.", Prefix)
            Kasutanud[id] = true
        }
    }
    menu_destroy(menu)
    return PLUGIN_HANDLED
}

public RelvaEvent(id)
{
    if(Kiiirus[id])
    {
        set_user_maxspeed(id, get_pcvar_float(Kiirus))
    }
   
    if(Unlimited[id])
    {
        new iClip, iAmmo, iWeapName[33]
        new iWeap = get_user_weapon(id, iClip, iAmmo)
        get_weaponname(iWeap, iWeapName, 32)
       
        if(iWeap == CSW_KNIFE ||
        iWeap == CSW_HEGRENADE ||
        iWeap == CSW_SMOKEGRENADE ||
        iWeap == CSW_FLASHBANG ){
            return PLUGIN_HANDLED
        }
       
        new bpammo = cs_get_user_bpammo(id, iWeap)
        if (bpammo <= 199 ) {
            cs_set_user_bpammo(id, iWeap, 200)
        }
    }
    return PLUGIN_HANDLED
}

public Spawnimine(id)
{
    if (is_user_alive(id))
    {
        set_user_maxspeed(id, 320.0)
        set_user_gravity(id, 1.0)
        set_user_rendering(id,kRenderFxGlowShell,0,0, 0,kRenderTransAlpha, 250)
      set_user_footsteps(id, 0)
        Kiiirus[id] = false
        Kasutanud[id] = false
        Unlimited[id] = false
    }
}