[AMXX] Autobuy Bug Fix

Plugina autorid: Romanov ja UFPS.Team
Kirjeldus: Teatud autobuy scriptiga on võimalik serverit crashida. Kui sul veel see plugin peal pole, siis soovitan selle peale panna. Salvestab ka logi amxmodx/logs kausta.
Näiteks:

Kood:

L 02/09/2012 - 21:30:09: Autobuy bug use: lagan soz [82.xxx.58.xx] <STEAM_0:x:36679xx4>
L 02/09/2012 - 21:30:13: Autobuy bug use: lagan soz [82.xxx.58.xx] <STEAM_0:x:36679xx4>
L 02/09/2012 - 21:30:15: Autobuy bug use: lagan soz [82.xxx.58.xx] <STEAM_0:x:36679xx4>

Plugin:

Kood:

#include <amxmodx>

#define PLUGIN_NAME            "Fix AutoBuy Bug"
#define PLUGIN_VERSION  "1.1"
#define PLUGIN_AUTHOR  "PomanoB & UFPS.Team"

new g_logfile[64]

public plugin_init( )
{
        register_plugin( PLUGIN_NAME, PLUGIN_VERSION, PLUGIN_AUTHOR )

        register_clcmd( "cl_setautobuy", "cmd_check" )
        register_clcmd( "cl_setrebuy", "cmd_check" )

        get_time ( "autobuy_%Y%m.log", g_logfile, charsmax ( g_logfile ) )
}

public cmd_check( id )
{
        static arg[512], args, i
        args = read_argc( )

        for( i = 1; i < args; ++i )
        {
                read_argv( i, arg, charsmax( arg ) )

                if( is_cmd_long( arg, charsmax( arg ) ) )
                {
                        log_autobuy( id )
                        return PLUGIN_HANDLED
                }
        }

        return PLUGIN_CONTINUE
}

stock bool:is_cmd_long( string[], const len )
{
        static cmd[512]

        while( strlen( string ) )
        {
                strtok( string, cmd, charsmax( cmd ), string, len , ' ', 1 )

                if( strlen( cmd ) > 31 ) return true
        }

        return false
}

stock log_autobuy( id )
{
        static name[32], steamid[44], ip[16]
        get_user_ip( id, ip, charsmax( ip ), 1 )
        get_user_authid( id, steamid, charsmax( steamid ) )
        get_user_name( id, name, charsmax( name ) )

        log_to_file( g_logfile, "Autobuy bug use: %s [%s] <%s>", name, ip, steamid )
}

DOWNLOAD:

Väga hea